plugins {
    id 'java-library'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '2.0.147'
    id 'idea'
}

tasks.named('wrapper', Wrapper).configure {
    // Define wrapper values here so as to not have to always do so when updating gradlew.properties.
    // Switching this to Wrapper.DistributionType.ALL will download the full gradle sources that comes with
    // documentation attached on cursor hover of gradle classes and methods. However, this comes with increased
    // file size for Gradle. If you do switch this to ALL, run the Gradle wrapper task twice afterwards.
    // (Verify by checking gradle/wrapper/gradle-wrapper.properties to see if distributionUrl now points to `-all`)
    distributionType = Wrapper.DistributionType.BIN
}

version = mod_version
group = mod_group_id

List<String> archivedGameTestSuites = ['linking', 'writing', 'grammar', 'desk', 'binder', 'mixer', 'recipe']
List<String> selectedArchivedGameTestSuites = providers.gradleProperty('withArchivedGameTests')
        .map { it.toBoolean() }.orElse(false).get() ? archivedGameTestSuites
        : providers.gradleProperty('archivedGameTestSuites').orElse('').get()
                .split(',').collect { it.trim() }.findAll { !it.isEmpty() }
if (!archivedGameTestSuites.containsAll(selectedArchivedGameTestSuites)) {
    throw new GradleException("Unknown archived GameTest suite. Choose from: ${archivedGameTestSuites.join(', ')}")
}
String enabledGameTestNamespaces = ([mod_id] + selectedArchivedGameTestSuites.collect {
    "rivencraft_archive_${it}"
}).join(',')

sourceSets.main.resources {
    // Include resources generated by data generators.
    srcDir('src/generated/resources')

    // Exclude common development only resources from finalized outputs
    exclude("**/*.bbmodel") // BlockBench project files
    exclude("src/generated/**/.cache") // datagen cache files
}

// Archived suites use separate namespaces but share the same empty structure.
tasks.named('processResources', ProcessResources).configure {
    archivedGameTestSuites.each { suite ->
        from('src/main/resources/data/rivencraft/structure/empty.nbt') {
            into "data/rivencraft_archive_${suite}/structure"
        }
    }
}

repositories {
    maven {
        name = 'JaredsMaven'
        url = 'https://maven.blamejared.com'
        content {
            includeGroup 'mezz.jei'
            includeGroup 'net.mezzdev.config'
        }
    }
    maven { url = 'https://maven.createmod.net' }
    maven {
        url = 'https://www.cursemaven.com'
        content { includeGroup 'curse.maven' }
    }
    maven { url = 'https://maven.bai.lol' }
    maven {
        url = 'https://api.modrinth.com/maven'
        content { includeGroup 'maven.modrinth' }
    }
}

base {
    archivesName = mod_id
}

// Mojang ships Java 21 to end users in 1.21.1, so mods should target Java 21.
java.toolchain.languageVersion = JavaLanguageVersion.of(21)

neoForge {
    // Specify the version of NeoForge to use.
    version = project.neo_version

    parchment {
        mappingsVersion = project.parchment_mappings_version
        minecraftVersion = project.parchment_minecraft_version
    }

    // This line is optional. Access Transformers are automatically detected
    // accessTransformers = project.files('src/main/resources/META-INF/accesstransformer.cfg')

    // Default run configurations.
    // These can be tweaked, removed, or duplicated as needed.
    runs {
        client {
            client()
            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        server {
            server()
            programArgument '--nogui'
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        // This run config launches GameTestServer and runs all registered gametests, then exits.
        // By default, the server will crash when no gametests are provided.
        // The gametest system is also enabled by default for other run configs under the /test command.
        gameTestServer {
            type = "gameTestServer"
            // Keep generated test Ages separate from worlds used by the dev client/server.
            gameDirectory = project.file(project.findProperty('gameTestRunDir')
                    ?: layout.buildDirectory.dir('gametest-run').get().asFile)
            systemProperty 'neoforge.enabledGameTestNamespaces', enabledGameTestNamespaces
        }

        data {
            data()
            // example of overriding the workingDirectory set in configureEach above, uncomment if you want to use it
            // gameDirectory = project.file('run-data')

            // Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
            programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
        }

        // applies to all the run configs above
        configureEach {
            // Recommended logging data for a userdev environment
            // The markers can be added/remove as needed separated by commas.
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            systemProperty 'forge.logging.markers', 'REGISTRIES'

            // Recommended logging level for the console
            // You can set various levels here.
            // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
            logLevel = org.slf4j.event.Level.DEBUG
        }
    }

    mods {
        // define mod <-> source bindings
        // these are used to tell the game which sources are for which mod
        // multi mod projects should define one per mod
        "${mod_id}" {
            sourceSet(sourceSets.main)
        }
    }
}

// Every default run gets a fresh world. Failed worlds stay available until a
// successful run; caller-supplied directories are never managed here.
boolean customGameTestRunDir = providers.gradleProperty('gameTestRunDir').isPresent()
File dedicatedGameTestBuildDir = layout.buildDirectory.get().asFile
File dedicatedGameTestDir = layout.buildDirectory.dir('gametest-run').get().asFile
File dedicatedGameTestWorld = new File(dedicatedGameTestDir, 'world')
File gameTestSuccessMarker = new File(dedicatedGameTestDir, '.last-gametest-succeeded')
def prepareGameTestWorld = tasks.register('prepareGameTestWorld') {
    onlyIf { !customGameTestRunDir }
    doLast {
        java.nio.file.Files.deleteIfExists(gameTestSuccessMarker.toPath())
        File preserved = GameTestWorlds.preserve(dedicatedGameTestBuildDir, dedicatedGameTestDir)
        if (preserved != null) logger.lifecycle('Preserved GameTest world for inspection at {}', preserved)
    }
}
def finishGameTestWorld = tasks.register('finishGameTestWorld') {
    onlyIf { !customGameTestRunDir }
    doLast {
        if (gameTestSuccessMarker.exists()) {
            GameTestWorlds.clean(dedicatedGameTestBuildDir, dedicatedGameTestDir)
            java.nio.file.Files.delete(gameTestSuccessMarker.toPath())
        } else {
            File preserved = GameTestWorlds.preserve(dedicatedGameTestBuildDir, dedicatedGameTestDir)
            if (preserved != null) logger.lifecycle('Preserved GameTest world for inspection at {}', preserved)
        }
    }
}
tasks.named('runGameTestServer').configure {
    dependsOn(prepareGameTestWorld)
    finalizedBy(finishGameTestWorld)
    doLast {
        if (!customGameTestRunDir) {
            GameTestWorlds.check(dedicatedGameTestBuildDir, dedicatedGameTestDir)
            java.nio.file.Files.createFile(gameTestSuccessMarker.toPath())
        }
    }
}

class GameTestWorlds {
    static void check(File buildDir, File runDir) {
        [buildDir, runDir, new File(runDir, 'world'), new File(runDir, 'failed-worlds')].each { path ->
            if (java.nio.file.Files.isSymbolicLink(path.toPath())) {
                throw new GradleException("Refusing to manage a symlinked GameTest path: ${path}")
            }
        }
    }

    static File preserve(File buildDir, File runDir) {
        File world = new File(runDir, 'world')
        if (!world.exists()) return null
        check(buildDir, runDir)
        if (!world.isDirectory()) throw new GradleException("Expected a GameTest world directory: ${world}")
        File failures = new File(runDir, 'failed-worlds')
        java.nio.file.Files.createDirectories(failures.toPath())
        String snapshot = java.time.format.DateTimeFormatter.ofPattern('yyyyMMdd-HHmmss-SSS')
                .format(java.time.LocalDateTime.now()) + '-' + java.util.UUID.randomUUID()
        File destination = new File(failures, snapshot)
        java.nio.file.Files.move(world.toPath(), destination.toPath())
        return destination
    }

    static void clean(File buildDir, File runDir) {
        check(buildDir, runDir)
        [new File(runDir, 'world'), new File(runDir, 'failed-worlds')].each { root ->
            if (root.exists()) {
                java.nio.file.Files.walk(root.toPath()).withCloseable { paths ->
                    paths.sorted(java.util.Comparator.reverseOrder()).forEach { path ->
                        java.nio.file.Files.delete(path)
                    }
                }
            }
        }
    }
}

// Sets up a dependency configuration called 'localRuntime'.
// This configuration should be used instead of 'runtimeOnly' to declare
// a dependency that will be present for runtime testing but that is
// "optional", meaning it will not be pulled by dependents of this mod.
configurations {
    runtimeClasspath.extendsFrom localRuntime
}

dependencies {
    // Create bundles the Ponder APIs used by the optional snapshot preview.
    // Keep them on the compile classpath without forcing either mod at runtime.
    compileOnly "net.createmod.ponder:ponder-neoforge:${ponder_version}+mc${minecraft_version}"
    compileOnly "maven.modrinth:immersive-portals-neoforge:${immersive_portals_version}"
    implementation "curse.maven:dynamicdimension-ar-edition-1469680:${dynamic_dimensions_file_id}"
    implementation "lol.bai:badpackets:neo-${badpackets_version}"
    // JEI integration is isolated in its plugin and absent from the published runtime dependencies.
    compileOnly "mezz.jei:jei-${minecraft_version}-neoforge-api:${jei_version}"
    // Opt in to JEI for a dev client with -PwithJei=true.
    if (providers.gradleProperty('withJei').map { it.toBoolean() }.orElse(false).get()) {
        localRuntime "mezz.jei:jei-${minecraft_version}-neoforge:${jei_version}"
    }

    // Example mod dependency using a mod jar from ./libs with a flat dir repository
    // This maps to ./libs/coolmod-${mc_version}-${coolmod_version}.jar
    // The group id is ignored when searching -- in this case, it is "blank"
    // implementation "blank:coolmod-${mc_version}:${coolmod_version}"

    // Example mod dependency using a file as dependency
    // implementation files("libs/coolmod-${mc_version}-${coolmod_version}.jar")

    // Example project dependency using a sister or child project:
    // implementation project(":myproject")

    // For more info:
    // http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
    // http://www.gradle.org/docs/current/userguide/dependency_management.html
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
var generateModMetadata = tasks.register("generateModMetadata", ProcessResources) {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            loader_version_range   : loader_version_range,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
    ]
    inputs.properties replaceProperties
    expand replaceProperties
    from "src/main/templates"
    into "build/generated/sources/modMetadata"
}
// Include the output of "generateModMetadata" as an input directory for the build
// this works with both building through Gradle and the IDE.
sourceSets.main.resources.srcDir generateModMetadata
// To avoid having to run "generateModMetadata" manually, make it run on every project reload
neoForge.ideSyncTask generateModMetadata

// Example configuration to allow publishing using the maven-publish plugin
publishing {
    publications {
        register('mavenJava', MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/repo"
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

// IDEA no longer automatically downloads sources/javadoc jars for dependencies, so we need to explicitly enable the behavior.
idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}